Base STO-nG

Un article de Wikipédia, l'encyclopédie libre.

Une base STO-nG est une base utilisée en chimie numérique, c'est-à-dire un ensemble de fonctions utilisées afin de créer des orbitales moléculaires. Plus précisément, une base STO-nG est une base minimale, dans laquelle la lettre n désigne le nombre de fonctions primitives gaussiennes que comprend une base simple. Pour les bases minimales, les orbitales de cœur et de valence sont représentées par le même nombre de fonctions primitives gaussiennes Φ_i. Ainsi, une base STO-3G pour la description de l'orbitale 1s de l'atome d'hydrogène est une combinaison linéaire de 3 fonctions primitives gaussiennes. Il est aisé de calculer l'énergie d'un électron de l'orbitale 1s de l'atome d'hydrogène représenté dans les bases STO-nG.
Dans les sections suivantes, la structure des bases minimales STO-nG sont expliquées en se basant sur l'exemple de l'atome H.

Sommaire

1 Description
- 1.1 Base STO-1G
- 1.2 Base STO-2G
2 Calcul de l'énergie électronique dans les bases STO-nG
- 2.1 Annexe
3 Références

[modifier] Description

[modifier] Base STO-1G

Ici, ψ(1s_H)=ψ(STO-1G)=c₁Φ₁ dans laquelle c₁=1 et $\mathbf \phi_1 = \left (\frac{2\alpha_1}{\pi} \right )^{0,75}e^{-\alpha_1 r^2}$ . La valeur optimale de α₁ est celle qui donne la valeur minimale de l'énergie pour l'électron 1s de l'atome d'hydrogène. L'exposant α₁ pour la base STO-1G peut être déduit manuellement en dérivant l'énergie par rapport à l'exposant et en prenant sa valeur en 0.
La valeur de α₁ est donc : $\alpha_1 = \frac{8 Z^2}{9 \pi} = 0,28294212$ et, pour cette valeur, l'énergie d'un électron 1s d'un atome H peut être évaluée à -0,42441318 hartree. L'expression de l'énergie de l'électron 1s de l'atome H est fonction seulement de c₁ et d'autres constantes fondamentales comme π. Par convenance, les détails de la base sont représentés comme ci-dessous :

STO-1G	$\mathbf \alpha$	$\mathbf c$
	0,2829421200	1,0000000000

[modifier] Base STO-2G

En général, une base STO-nG est une combinaison linéaire de n fonctions gaussiennes primitives. Les bases STO-nG sont habituellement représentées par leurs exposants et les coefficients correspondants. Ainsi, un base STO-2G^[1] qui est une combinaison linéaire de deux fonctions primitives gaussiennes peut être représentée comme ci-dessous :

STO-2G	$\mathbf \alpha$	$\mathbf c$
	0,1309756377×10¹	0,4301284983
	0,2331359749	0,6789135305

[modifier] Calcul de l'énergie électronique dans les bases STO-nG

L'énergie électronique d'un système est calculée comme la valeur attendue du hamiltonien électronique :

$\mathbf E_{elec} = \frac{<\psi_{STO-nG}|\mathbf \hat{H}_e|\psi_{STO-nG}>}{<\psi_{STO-nG}|\psi_{STO-nG}>}$

où $\mathbf \hat{H}_e$ est le hamiltonien électronique du système. Les valeurs attendues peuvent être analytiquement obtenues seulement pour un système à deux corps, comme un atome d'hydrogène par exemple. Le hamiltonien pour un atome d'hydrogène est donné par :

$\mathbf\hat{H}_e = -\frac{\nabla^2}{2}-\frac{Z}{r}$ .

Les intégrales exactes pour l'énergie cinétique, les valeurs attendues de l'énergie potentielle et les intégrales de recouvrement peuvent être obtenues comme indiqué ci-après :

$\mathbf E_{elec} = \frac{<\psi_{STO-nG}|-\frac{\nabla^2}{2}-\frac{Z}{r}|\psi_{STO-nG}>}{<\psi_{STO-nG}|\psi_{STO-nG}>}$

$\mathbf E_{elec} = \frac{<\sum_{i=1}^n c_i \phi_i|-\frac{\nabla^2}{2}|\sum_{j=1}^n c_j \phi_j> + <\sum_{i=1}^n c_i \phi_i|-\frac{Z}{r}|\sum_{j=1}^n c_j \phi_j>}{<\sum_{i=1}^n c_i \phi_i|\sum_{j=1}^n c_j \phi_j>}$

$\mathbf E_{elec} = \frac{<\sum_{i=1}^n c_i \phi_i|T|\sum_{j=1}^n c_j \phi_j> + <\sum_{i=1}^n c_i \phi_i|V|\sum_{j=1}^n c_j \phi_j>}{<\sum_{i=1}^n c_i \phi_i|\sum_{j=1}^n c_j \phi_j>}$

Les valeurs attendues de l'énergie totale peuvent être séparées en trois parties, la partie énergie cinétique, l'énergie potentielle attendue et les intégrales de recouvrement.

$\mathbf E_{elec} = \frac{<T>+<V>}{S}$ où

$\mathbf <T> = \frac {6\sqrt{2}\sum_{i=1}^n \sum_{j=1}^n c_i c_j (\alpha_i\alpha_j)^{7/4}}{(\alpha_i+\alpha_j)^{5/2}}$ ,

$\mathbf <V> = \frac {-4\sqrt{2}Z \sum_{i=1}^n \sum_{j=1}^n c_i c_j (\alpha_i\alpha_j)^{3/4}}{\sqrt{\pi}(\alpha_i+\alpha_j)}$ ,

$\mathbf S = \frac {2\sqrt{2} \sum_{i=1}^n \sum_{j=1}^n c_i c_j (\alpha_i\alpha_j)^{3/4}}{(\alpha_i+\alpha_j)^{3/2}}$ .

Ainsi, lors de l'utilisation d'une base STO-nG avec n gaussiennes primitives, il y a n² intégrales d'énergie cinétique, n² intégrales d'énergie potentielle et n² intégrales de recouvrement. Ainsi, avec n fonctions primitives gaussiennes dans la base, on a besoin de calculer 3n² intégrales.

[modifier] Annexe

Les bases STO-nG (pour n=2, 3 et 6) peuvent être consultées depuis la banque de données en ligne^[2] et l'énergie de l'électron 1s de l'atome H peut facilement être calculée à la main ou en utilisant un programme simple. Ci-dessous est proposé un programme en Fortran 77 dans laquelle l'expression de l'énergie est explicitement donnée et en donnant la base comme donnée d'entrée, l'énergie est obtenue en sortie.

     !----------------------------------------------------------------
     ! PROGRAM sto_ng CALCULATES THE ENERGY OF 1s ELECTRON OF "H" ATOM
     ! OR OTHER HYDROGENIC ATOMIC SYSTEMS WITH MINIMAL BASIS SETS. THE
     ! PROGRAM CAN BE EASILY EXTENDED FOR LARGER BASIS SETS. 
     !----------------------------------------------------------------
     PROGRAM sto_ng
     IMPLICIT NONE
     !----------------------------------------------------------------
     ! i AND j : DUMMY INDICES
     !       n : NUMBER OF PRIMITIVE GTOs
     !       Z : ATOMIC NUMBER
     !----------------------------------------------------------------
     INTEGER i, j, n, Z
     !----------------------------------------------------------------
     !  V(i,j) : i,j TH ELEMENT OF THE POTENTIAL ENERGY MATRIX
     !  T(i,j) : i,j TH ELEMENT OF THE KINETIC ENERGY MATRIX
     !  S(i,j) : i,j TH ELEMENT OF THE OVERLAP INTEGRAL MATRIX
     !      VI : TOTAL SUM OF ALL POTENTIAL ENERGY INTEGRALS
     !      TI : TOTAL SUM OF ALL KINETIC ENERGY INTEGRALS
     !      SI : TOTAL SUM ALL OF OVERLAP INTEGRALS
     !    c(i) : i TH COEFFICIENT
     !alpha(i) : i TH EXPONENT
     !----------------------------------------------------------------
     DOUBLE PRECISION V(100,100), T(100,100), S(100,100)
     DOUBLE PRECISION alpha(100), c(100), VI, TI, SI, PI
     PI=3.1415926535898D0
     OPEN(UNIT=1, FILE="input.txt")
     OPEN(UNIT=2, FILE="output.txt")
     READ(1,*)Z,n
     DO i=1,n
        READ(1,*)alpha(i),c(i)
     ENDDO
    !----------------------------------------------------------------
    ! CALCULATION OF OVERLAP INTEGRALS AND THEIR SUMMATION
    !----------------------------------------------------------------
     DO i=1,n
        DO j=1,n
          S(i,j)=c(i)*c(j)*2.0D0*SQRT(2.0D0)*(alpha(i)*alpha(j))**0.75D
    &0/(alpha(i)+alpha(j))**(1.5D0)
        ENDDO
     ENDDO
     SI=0.0D0
     DO i=1,n
        DO j=1,n
           SI=SI+S(i,j)
       ENDDO
     ENDDO
    !----------------------------------------------------------------
    ! CALCULATION OF KINETIC ENERGY INTEGRALS AND THEIR SUMMATION
    !----------------------------------------------------------------
     DO i=1,n
        DO j=1,n
        T(i,j)=c(i)*c(j)*6.0D0*SQRT(2.0D0)*(alpha(i)*alpha(j))**1.75D0/
    &(alpha(i)+alpha(j))**(2.5D0)
       ENDDO
     ENDDO
     TI=0.0D0
     DO i=1,n
        DO j=1,n
           TI=TI+T(i,j)
       ENDDO
     ENDDO
    !----------------------------------------------------------------
    ! CALCULATION OF POTENTIAL ENERGY INTEGRALS AND THEIR SUMMATION
    !----------------------------------------------------------------
     DO i=1,n
        DO j=1,n
          V(i,j)=-c(i)*c(j)*4.0D0*SQRT(2.0D0)*Z*(alpha(i)*alpha(j))**0.
    &75D0/(SQRT(PI)*(alpha(i)+alpha(j)))
        ENDDO
     ENDDO
     VI=0.0D0
     DO i=1,n
        DO j=1,n
           VI=VI+V(i,j)
       ENDDO
     ENDDO
     WRITE(2,*)"\n\nBasis set :\n"
     WRITE(2,002)"ALPHA(i)","C(i)"
     DO i=1,n
        WRITE(2,003)alpha(i),c(i)
     ENDDO
     WRITE(2,001)"\n\nK.E. integral is    :", TI," hartree"
     WRITE(2,001)"\nP.E. integral is    :", VI," hartree"
     WRITE(2,001)"\nOverlap Integral is :", SI," hartree"
     WRITE(2,001)"\nEnergy of H atom is :", (VI+TI)/SI," hartree/partic
    &le"
     WRITE(2,001)"\nENERGY of H atom is :",(VI+TI)*27.211397D0/SI," e.V
    &./particle"
     WRITE(2,001)"\nENERGY of H atom is :",(VI+TI)*627.509D0/SI," kcal/
    &mol"
     WRITE(2,001)"\nENERGY of H atom is :",(VI+TI)*2625.51D0/SI," kJ/mo
    &l"
     WRITE(2,001)"\nENERGY of H atom is :",(VI+TI)*219475D0/SI," cm-1"
 001 FORMAT(A,D20.10,A)
 002 FORMAT(8X,A,19X,A)
 003 FORMAT(D20.10,6X,D20.10)
 004 FORMAT(D20.10)
     CLOSE(1)
     CLOSE(2)
     STOP
     END

     INPUT FILE DETAILS
     FILE : input.txt
      1                                       ! ATOMIC NUMBER
      2                                       ! NO. OF PRIMITIVE GTOs
      0.1309756377D+01  0.4301284983D+00      ! BASIS SET  alpha c
      0.2331359749D+00  0.6789135305D+00

     OUTPUT FILE DETAILS
     FILE : output.txt
     Basis set :
         ALPHA(i)                   C(i)
     0.1309756377E+01          0.4301284983E+00
     0.2331359749E+00          0.6789135305E+00
     K.E. integral is    :    0.7348827001E+00 hartree
     P.E. integral is    :   -0.1189280102E+01 hartree
     Overlap Integral is :    0.1000000000E+01 hartree
     Energy of H atom is :   -0.4543974016E+00 hartree/particle
     ENERGY of H atom is :   -0.1236478809E+02 e.V./particle
     ENERGY of H atom is :   -0.2851384591E+03 kcal/mol
     ENERGY of H atom is :   -0.1193024922E+04 kJ/mol
     ENERGY of H atom is :   -0.9972886973E+05 cm-1