Image:Flyback continuous discontinuous french.svg
Un article de Wikipédia, l'encyclopédie libre.
Flyback_continuous_discontinuous_french.svg (Fichier SVG, résolution de 600 × 480 pixels, taille : 35 Kio)
| Ce fichier provient de Wikimedia Commons?. Les informations le concernant sont affichées ci-dessous (procédure). |
[edit] Summary
| Description |
Français : Vue des modes de conduction continue et discontinue d'une flyback
English: Evolution of the output voltage of a flyback converter with the output current.
|
|---|---|
| Source |
own work/travail personnel |
| Date |
07/04/2008 |
| Author |
Yves-Laurent Allaert |
| Permission (Reusing this image) |
|
[edit] Gnuplot script
Save this script to file "Flyback_continuous_discontinuous_french" then run the command line "gnuplot Flyback_continuous_discontinuous_french", you will get Flyback_continuous_discontinuous_french.svg, if you have well installed gnuplot 4.0 or later.
# This file is used to plot the domains of continuous and
# discontinuous operation of a Flyback converter
# graph configuration
set terminal svg enhanced fname "Times" fsize 16
set encoding iso_8859_15
unset title
set key off
set mxtics
set mytics
set grid xtics ytics
set ylabel "Tension normalisée" font "Times, 20"
set xlabel "Courant normalisé" font "Times, 20"
set format y '%0.1f'
set format x "%0.2f"
set samples 1000
# labels displayed on the graph
set label 1 "Conduction\n diccontinue" at 0.05,9 front center
set label 2 "Conduction\n continue" at 0.19,9 center
set label 4 "\\alpha=0,1" at 0.21,1.05 right front nopoint tc lt 1
set label 5 "\\alpha=0,3" at 0.21,2.6 right front nopoint tc lt 2
set label 6 "\\alpha=0,5" at 0.21,5.5 right front nopoint tc lt 3
set label 7 "\\alpha=0,7" at 0.21,12.1 right front nopoint tc lt 4
# normalized voltage=g(normalized current)
m=5
fdisc(x,D) = m*D**2/(2*x)
fcont(x,D) = m*D/(1-D)
g(x,D) = fdisc(x,D)<=fcont(x,D)?fcont(x,D):fdisc(x,D)
#parametric functions for plotting of domain limit
set parametric
my_x(t) = t*(1-t)/(2)
my_y(t) = m*t/(1-t)
set output "Flyback_continuous_discontinuous_french.svg"
# the plot is set as parametric, so each curve is defined by two values: x,y
plot [0:1][0:0.25][0:20] t,g(t,0.1) with lines lw 2 lt 1, \
t,g(t,0.3) with lines lw 2 lt 2, \
t,g(t,0.5) with lines lw 2 lt 3, \
t,g(t,0.7) with lines lw 2 lt 4, \
my_x(t),my_y(t) with lines lw 2 lt 5
Historique du fichier
Cliquer sur une date et une heure pour voir le fichier tel qu’il était à ce moment-là
| Date et heure | Dimensions | Utilisateur | Commentaire | |
|---|---|---|---|---|
| actuel | 7 avril 2008 à 23:19 | 600×480 (35 Kio) | Yves-Laurent | (== Summary == {{Information |Description={{fr|Vue des modes de conduction continue et discontinue d'une flyback}} {{en|Evolution of the output voltage of a flyback converter with the output current.}} |Source=own work/travail personnel |Date=07/04/2008 |A) |
Pages contenant l’image
Les pages ci-dessous contiennent cette image :
