Image:Diode mosfet fr.png

Un article de Wikipédia, l'encyclopédie libre.

• Image
• Historique du fichier
• Pages contenant l’image

Taille de cet aperçu : 800 × 560 pixels
Image en plus haute résolution‎ (1 500 × 1 050 pixels, taille du fichier : 66 Kio, type MIME : image/png)

[modifier] Summary

traduction en français de Diode_mosfet.png du wikipédia anglais qui a été créée originalement par Cyril BUTTAY

Current vs Voltage curves of a MOSFET operating in the ohmic region and a diode. At low current values, the voltage drop in the MOSFET is less than in the diode (due to its threshold voltage). When the current increases, the forward voltage drop of the diode does not increase as much as that of the MOSFET. In consequence, for high currents, the losses (current times voltage) are less in the diode than in the MOSFET. However, by connecting several MOSFETs in parallel, it is possible to reduce their R_DSon as can be seen in the figure (orange curve). Paralleling several diodes will not modify their threshold voltage.

This file has been generated using gnuplot 4.0 and the following source code:

# Caractéristiques statique comparées d'une diode et d'un
# MOSFET pour montrer l'intérêt du redressement synchrone

#  configuration du tracé
set terminal postscript eps enhanced "Times-Roman" 24 color solid
set encoding iso_8859_15
unset title
set style line 1 lt 1 lw 3 pt 0 ps 0
set style line 2 lt 3 lw 3 pt 0 ps 0
set style line 3 lt 7 lw 1 pt 0 ps 0
set style line 4 lt 8 lw 3 pt 0 ps 0
set border 15 lt 7 lw 4
set mxtics
set mytics
set grid xtics ytics
set xlabel "Courant (A)"
set ylabel "tension (V)"
set format y '%0.1f'
set format x "%0.0f"
set key bottom right
set samples 1000
# chute de tension directe dans la diode
diode(x)=0.026*log(x*1e9+1)
#MOSFET resistive behaviour, rdson=20mohms
MOSFET(x)=x*0.02
#MOSFET resistive behaviour, rdson=10mohms
MOSFET2(x)=x*0.01
#arrows
set arrow 1 from 0,0.7 to 31.6,0.7 heads ls 3
set arrow 2 from 31.6,0.7 to 60,0.7 heads ls 3
set arrow 3 from 31.6,0.6 to 31.6, 0.72 nohead ls 3
#labels
set label 1 'Moins de pertes dans' center at 16,0.79 font "Times, 18"
set label 2 'le MOSFET de 20 m{/Symbol W}' center at 16,0.74 font "Times, 18"
set label 3 'Moins de pertes dans la diode' center at 46,0.74 font "Times,18" front

set output "diode_mosfet_fr.eps"
plot [0:60][0:1] MOSFET(x) ls 1 title 'MOSFET R{_{DSon}}=20 m{/Symbol W}',\
        MOSFET2(x) ls 4 title 'MOSFET R{_{DSon}}=10 m{/Symbol W}',\
        diode(x) ls 2 title 'Diode'

Then it is converted in png format using the following command (Linux):

convert -density 300 diode_mosfet_fr.eps diode_mosfet_fr.png

[modifier] Licensing

GFDL

Vous avez la permission de copier, distribuer et/ou modifier ce document selon les termes de la licence de documentation libre GNU, version 1.2 ou plus récente publiée par la Free Software Foundation ; sans sections inaltérables, sans texte de première page de couverture et sans texte de dernière page de couverture.

	Après avoir vérifié la validité de sa licence, cette image libre devrait être transférée vers Wikimedia Commons.
	Vous pouvez vous aider de l'assistant de transfert vers Commons, puis apposer sur cette page le modèle : {{Désormais sur Commons|nom de l'image sur commons}}.

Historique du fichier

Cliquer sur une date et une heure pour voir le fichier tel qu’il était à ce moment-là

• Recherche de doublons
• Modifier ce fichier en utilisant une application externe

  Consulter les instructions d'installation pour plus d'information.

Pages contenant l’image