Image:Boost continuous discontinuous french.png
Un article de Wikipédia, l'encyclopédie libre.
Taille de cet aperçu : 800 × 560 pixels
Image en plus haute résolution (1 500 × 1 050 pixels, taille du fichier : 62 Kio, type MIME : image/png)
| Ce fichier provient de Wikimedia Commons?. Les informations le concernant sont affichées ci-dessous (procédure). |
[edit] Summary
french translation of Boost continuous discontinuous.png by Cyril BUTTAY
graph Us=f(Io) of a boost converter. This figure has been made using gnuplot 4.0 with the following source (released as belonging to the public domain):
# This file is used to plot the domains of continuous and
# discontinuous operation of a boost converter
# graph configuration
set terminal postscript eps enhanced "Times-Roman" 24
set encoding iso_8859_15
unset title
set style line 1 lt 10 lw 3 pt 0 ps 0
set style line 2 lt 3 lw 3 pt 0 ps 0
set border 15 lt 10 lw 4
set mxtics
set mytics
set grid xtics ytics
set ylabel "Tension normalisée"
set xlabel "Courant normalisé"
set format y '%0.1f'
set format x "%0.2f"
set samples 1000
# labels displayed on the graph
set label 1 'diccontinue' at 0.075,1.6 center
set label 2 'conduction continue' at 0.175,3.5 center
set label 3 '{/Symbol a}=0,0' at 0.24,0.8 right
set label 4 '{/Symbol a}=0,2' at 0.24,1.45 right
set label 5 '{/Symbol a}=0,4' at 0.24,1.9 right
set label 6 '{/Symbol a}=0,6' at 0.24,2.7 right
set label 7 '{/Symbol a}=0,8' at 0.24,5.2 right
# normalized voltage=g(normalized current)
fdisc(x,D) = D**2/(2*x)+1
fcont(x,D) = 1/(1-D)
g(x,D) = fdisc(x,D)<=fcont(x,D)?fcont(x,D):fdisc(x,D)
#parametric functions for plotting of domain limit
set parametric
my_x(t) = (1-t)/2*t
my_y(t) = 1/(1-t)
set output "boost_continuous_discontinuous_french.eps"
# the plot is set as parametric, so each curve is defined by two values: x,y
plot [0:1][0:0.25][0:6] t,g(t,0) ls 1 title '', \
t,g(t,0.2) ls 1 title '', \
t,g(t,0.4) ls 1 title '', \
t,g(t,0.6) ls 1 title '', \
t,g(t,0.8) ls 1 title '', \
my_x(t),my_y(t) ls 2 title ''
and the conversion in png format is made using convert (linux):
convert -density 300 boost_continuous_discontinuous_french.eps boost_continuous_discontinuous_french.png
[edit] Licensing
Historique du fichier
Cliquer sur une date et une heure pour voir le fichier tel qu’il était à ce moment-là
| Date et heure | Dimensions | Utilisateur | Commentaire | |
|---|---|---|---|---|
| actuel | 24 juillet 2006 à 12:31 | 1 500×1 050 (62 Kio) | Yves-Laurent | (== Summary == french translation of Boost continuous discontinuous.png by Cyril BUTTAY graph Us=f(Io) of a boost converter. This figure has been made using gnuplot 4.0 with the following source (released as belonging to the public domain): <pre> # This ) |
| 19 juillet 2006 à 11:27 | 1 500×1 050 (64 Kio) | Yves-Laurent | (== Summary == french translation of Boost continuous discontinuous.png by Cyril BUTTAY graph Us=f(Io) of a boost converter. This figure has been made using gnuplot 4.0 with the following source (released as belonging to the public domain): <pre># This f) | |
| 19 juillet 2006 à 10:49 | 1 500×1 050 (63 Kio) | Yves-Laurent | (french translation of Boost continuous discontinuous.png by Cyril BUTTAY graph Us=f(Io) of a boost converter. This figure has been made using gnuplot 4.0 with the following source (released as belonging to the public domain): <pre># This file is used to) |
Pages contenant l’image
Les pages ci-dessous contiennent cette image :
